CS4 Install per Script

option explicit
on error resume next

Dim oargs, wshell, fso, Architecture
Dim strComputer , objWMIService, colItems, objItem
Dim ClouString, ProgFile, cpf, regroot
Dim pubfldr, progdata, objfolder, rc

set oArgs=wscript.Arguments

if oArgs.Count <1 then
wscript.echo VBCRLF & "! FEHLER !" & VBCRLF & "! Fehlender Parameter !"
wscript.quit
End if

set fso = createobject("scripting.filesystemobject")
set wshell = createobject("wscript.shell")
strComputer = "."
Set objWMIService = GetObject("winmgmts:\\" & strComputer & "\root\cimv2")
Set colItems = objWMIService.ExecQuery("Select * from Win32_OperatingSystem",,48)

'BitBreite auslesen'
For Each objItem in colItems
Architecture = objItem.OSArchitecture
Next
'Umgebungsvariablen entsprechend der Bitbreite auslesen und verarbeiten
If Architecture="32-Bit" then
cpf =  wShell.ExpandEnvironmentStrings("%CommonProgramFiles%")
progfile = wShell.ExpandEnvironmentStrings("%ProgramFiles%")
regroot = "HKLM\Software"
ElseIf Architecture="64-Bit" then
cpf =  wShell.ExpandEnvironmentStrings("%CommonProgramFiles(x86)%")
progfile = wShell.ExpandEnvironmentStrings("%ProgramFiles(x86)%")
regroot = "HKLM\Software\Wow6432Node"
end if

pubfldr = wShell.ExpandEnvironmentStrings("%Public%")
progdata = wShell.ExpandEnvironmentStrings("%ProgramData%")

if oArgs(0) = "/install" then

'Add ActiveSetup to switch off Air Eula via Flag File in %AppData%...
'Der Ort fürs ActiveSetup in der Registry ändert sich nicht, deswegen harter Pfad'
wshell.regwrite "HKLM\Software\Microsoft\Active Setup\Installed Components\{A2881E09-38DB-4F79-9135-00FDA01768A7}","","REG_SZ"
wshell.regwrite "HKLM\Software\Microsoft\Active Setup\Installed Components\{A2881E09-38DB-4F79-9135-00FDA01768A7}\StubPath", progfile & "\Adobe\Appdata\appdata.exe", "REG_SZ"
wshell.regwrite "HKLM\Software\Microsoft\Active Setup\Installed Components\{A2881E09-38DB-4F79-9135-00FDA01768A7}\Version", "1.0", "REG_SZ"
if not fso.folderexists(progfile & "\Adobe\Appdata") then fso.createfolder (progfile & "\Adobe\Appdata")
if not fso.fileexists(progfile & "\Adobe\Appdata\appdata.exe") then fso.CopyFile oargs(1) & "\Data\appdata.exe", progfile & "\Adobe\Appdata\"


'Changing behaviour of Appwiz.cpl
'Acrobat.com
wshell.regwrite regroot & "\Microsoft\Windows\CurrentVersion\UnInstall\com.adobe.mauby.4875E02D9FB21EE389F73B8D1702B320485DF8CE.1\NoRemove", "1", "REG_DWORD"
'Adobe Air
wshell.regwrite regroot & "\Microsoft\Windows\CurrentVersion\UnInstall\Adobe AIR\SystemComponent", "1", "REG_DWORD"
'Adobe Flash Player 10 Plugin
wshell.regwrite regroot & "\Microsoft\Windows\CurrentVersion\UnInstall\{03DEEAD2-F3B7-45BF-9006-A25D015F00D2}\SystemComponent", "1", "REG_DWORD"
'Adobe Flash Player 10 ActiveX
wshell.regwrite regroot & "\Microsoft\Windows\CurrentVersion\UnInstall\{3A6829EF-0791-4FDD-9382-C690DD0821B9}\SystemComponent", "1","REG_DWORD"
'Adobe Media Player
wshell.regwrite regroot & "\Microsoft\Windows\CurrentVersion\UnInstall\com.adobe.amp.4875E02D9FB21EE389F73B8D1702B320485DF8CE.1\SystemComponent", "1", "REG_DWORD"
'Adobe Creative Suite 4 Design Premium
wshell.regwrite regroot & "\Microsoft\Windows\CurrentVersion\UnInstall\Adobe_55230b0b70661df0f212e88f0b655f7\NoModify","1", "REG_DWORD"
wshell.regwrite regroot & "\Microsoft\Windows\CurrentVersion\UnInstall\Adobe_55230b0b70661df0f212e88f0b655f7\NoRemove", "1", "REG_DWORD"

'Disable Adobe Air Updater
wshell.regwrite regroot & "Policies\Adobe\AIR\UpdateDisabled", "1", "REG_DWORD"

'Dateien und Ordner an gemeinsamen Speicherorten werden bearbeitet
if fso.fileexists(pubfldr & "\Desktop\Adobe Acrobat 9 Pro.lnk") then fso.deletefile (pubfldr & "\Desktop\Adobe Acrobat 9 Pro.lnk")
if fso.fileexists(progdata & "\Microsoft\Windows\Start Menu\Programs\Adobe\Adobe Media Player.lnk") then fso.movefile progdata & "\Microsoft\Windows\Start Menu\Programs\Adobe\Adobe Media Player.lnk", progdata & "\Microsoft\Windows\Start Menu\Programs\Adobe Design Premium CS4\Adobe Media Player.lnk"
set objFolder = fso.GetFolder(progdata & "\Microsoft\Windows\Start Menu\Programs\Adobe")
if objFolder.Size="0" then fso.deletefolder progdata & "\Microsoft\Windows\Start Menu\Programs\Adobe"
if fso.fileexists(progdata & "\Microsoft\Windows\Start Menu\Programs\Acrobat.com.lnk") then fso.deletefile (progdata & "\Microsoft\Windows\Start Menu\Programs\Acrobat.com.lnk")


elseif oArgs(0) = "/uninstall" then

rc = wshell.run ("""" & cpf & "\Adobe\Installers\55230b0b70661df0f212e88f0b655f7\Setup.exe""" & " --uninstall=1",1 ,True)
rc = wshell.run ("""" & cpf & "\Adobe AIR\Versions\1.0\Resources\Adobe AIR Updater.exe""" & " -arp:uninstall",1 ,True)

'Delete obsolete Folders
if fso.folderexists (progfile & "\Adobe\Adobe Bridge CS4") then fso.deletefolder progfile & "\Adobe\Adobe Bridge CS4", true
if fso.folderexists (progfile & "\Adobe\Adobe Extension Manager CS4") then fso.deletefolder progfile & "\Adobe\Adobe Extension Manager CS4", true
if fso.folderexists (progfile & "\Adobe\Adobe Flash CS4") then fso.deletefolder progfile & "\Adobe\Adobe Flash CS4", true
if fso.folderexists (progfile & "\Adobe\Adobe Illustrator CS4") then fso.deletefolder progfile & "\Adobe\Adobe Illustrator CS4", true
if fso.folderexists (progfile & "\Adobe\Adobe InDesign CS4") then fso.deletefolder progfile & "\Adobe\Adobe InDesign CS4", true
if fso.folderexists (progfile & "\Adobe\AppData") then fso.deletefolder progfile & "\Adobe\AppData", true
if fso.folderexists (progdata & "\Microsoft\Windows\Start Menu\Programs\Adobe Design Premium CS4") then fso.deletefolder progdata & "\Microsoft\Windows\Start Menu\Programs\Adobe Design Premium CS4", true
if fso.folderexists (cpf & "\Adobe\CS4ServiceManager") then fso.deletefolder cpf & "\Adobe\CS4ServiceManager", true
if fso.folderexists (cpf & "\Adobe\Installers") then fso.deletefolder cpf & "\Adobe\Installers", true

'covering the tracks in registry
'Active Setup
wshell.regdelete "HKLM\SOFTWARE\Microsoft\Active Setup\Installed Components\{A2881E09-38DB-4F79-9135-00FDA01768A7}\"
'Adobe Media Player
wshell.regdelete regroot & "\Microsoft\Windows\CurrentVersion\UnInstall\com.adobe.amp.4875E02D9FB21EE389F73B8D1702B320485DF8CE.1\"
'Acrobat.com                                                                                                                        
wshell.regdelete regroot & "\Microsoft\Windows\CurrentVersion\UnInstall\com.adobe.mauby.4875E02D9FB21EE389F73B8D1702B320485DF8CE.1\"
'Air Updater'
wshell.regdelete regroot & "\Policies\Adobe\AIR\"

end if